Contents

# For...Next Statement

Repeats the statements between the For...Next block a specified number of times.

## 구문:

    For counter=start To end [Step step]
        statement-block
        [Exit For]
        statement-block
    Next [counter]

      For Each item In list
          statement-block
      [Exit For]
          statement-block
      Next [item]

## 변수:

counter: Loop counter initially assigned the value to the right of the equal sign (start). Only numeric variables are valid. The loop counter increases or decreases according to the variable step until end is passed.

start: Numeric variable that defines the initial value at the beginning of the loop.

end: Numeric variable that defines the final value at the end of the loop.

step: Sets the value by which to increase or decrease the loop counter. If step is not specified, the loop counter is incremented by 1. In this case, end must be greater than start. If you want to decrease counter, end must be less than start, and step must be assigned a negative value.

For...Next 루프는 매개 변수에 지정된 횟수만큼 루프의 모든 문을 반복합니다.

As the counter variable is decreased, LibreOffice Basic checks if the end value has been reached. As soon as the counter passes the end value, the loop automatically terminates.

For...Next 문을 중첩할 수 있습니다. Next 뒤에 변수를 지정하지 않을 경우 Next는 가장 최근의 For 문을 자동으로 참결합니다.

증분을 0으로 지정하면 For와 Next 사이의 문이 계속 반복됩니다.

When counting down the counter variable, LibreOffice Basic checks for overflow or underflow. The loop ends when counter exceeds end (positive Step value) or is less than end (negative Step value).

루프를 무조건 종료하려면 Exit For 문을 사용합니다. 이 문은 For...Next 루프 내에 있어야 합니다. 다음과 같이 If...Then 문을 사용하여 종료 조건을 테스트합니다.

      For...
          statement-block
          If condition = True Then Exit For
          statement-block
      Next

In nested For...Next loops, if you exit a loop unconditionally with Exit For, only one loop is exited.

## Examples

The following example uses two nested loops to sort a string array with 10 elements ( sEntry() ), that is filled with various contents:

    Sub ExampleSort
    Dim sEntry(9) As String
    Dim iCount As Integer, iCount2 As Integer
    Dim sTemp As String
        sEntry = Array("Jerry","Patty","Kurt","Thomas","Michael",_
                     "David","Cathy","Susie","Edward","Christine")
        For iCount = 0 To 9
            For iCount2 = iCount + 1 To 9
                If sEntry(iCount) > sEntry(iCount2) Then
                    sTemp = sEntry(iCount)
                    sEntry(iCount) = sEntry(iCount2)
                    sEntry(iCount2) = sTemp
                End If
            Next iCount2
        Next iCount
        For iCount = 0 To 9
            Print sEntry(iCount)
        Next iCount
    End Sub

This explores the content of an array to display each item it contains.

      Sub list_iteration
          cutlery = Array("fork", "knife", "spoon")
          For Each item in cutlery
              Print item
          Next ' item
      End Sub